Forum Coders' city Strona Gwna Coders' city
Nasza pasja to programowanie!
 

 PomocPomoc   SzukajSzukaj   UytkownicyUytkownicy   GrupyGrupy  RejestracjaRejestracja 
Archiwum starego forum + teoria    RSS & Panel/SideBar
 ProfilProfil   Zaloguj si, by sprawdzi wiadomociZaloguj si, by sprawdzi wiadomoci   ZalogujZaloguj 

Potrzebuj szybkiej odpowiedzi na moje pytanie... Zasady

[PowerPoint] Jak z prezentacji Power Point aktualizowac Excela



 
Odpowiedz do tematu    Forum Coders' city Strona Gwna -> Oprogramowanie biurowe
Zobacz poprzedni temat :: Zobacz nastpny temat  
Autor Wiadomo
ireks



Doczy: 01 Lis 2007
Posty: 8

PostWysany: Czw Sie 10, 2017 11:48 am  OP    Temat postu: [PowerPoint] Jak z prezentacji Power Point aktualizowac Excela Odpowiedz z cytatem Pisownia

Jak z prezentacji Power Point aktualizowac Excela (najlepiej przez VBA)
Jak odczytana wartosc z TextBox (w PP) zapisac w arkuszu Excela ?

Pojawia sie blad "Sub or Function not defined" gdy probuje wskazac odpowiedni Arkusz

Sheet2 to nazwa Skoroszytu
WartoscA - to wartosc do zapisania

------------
Kod:

    Private Sub CommandButton1_Click()

        Dim WartoscA As Integer

        Sheet2 = Workbooks("Book1.xlsx").Worksheets("Sheet2")
        Workbooks("Book1.xlsx").Worksheets("Sheet2").Activate()

        WartoscA = TextBox1_A.Text
        Range("A2").Value = WartoscA

    End Sub

Tytu tematu dostosowaem zgodnie z trecia posta- Samolot
Dodaem znaczniki kodu. Zobacz: znaczniki formatujce - jak stosowa.- Samolot
Powrt do gry
Zobacz profil autora Wylij prywatn wiadomo
karolinavb
Site Admin


Doczy: 25 Maj 2005
Posty: 7834

PostWysany: Sob Sie 12, 2017 7:04 am      Temat postu: Odpowiedz z cytatem Pisownia

Nie wiem czy dobrze zrozumiaam Twoje tumaczenie...
Zacznijmy w tym miejscu...
Kod:
'---------------------------------------------------
' kod w Slide Object module
'---------------------------------------------------
Option Explicit

Private Sub CmdZapisz_Click()
' przycisk CmdZapisz
    If Zapisz() = True Then
        MsgBox "Ok"
    End If
End Sub

Function Zapisz() As Boolean
' http://support.microsoft.com/default.aspx?scid=kb%3ben-us%3b178510
    On Error GoTo Zapisz_Error
    Dim XlApp                     As Object    'Excel.Application
    Dim XlWkb                     As Object    'Excel.Workbook
    Dim strXlFullName             As String
    ' pominelam sprawdzenie czy plik istnieje...
    strXlFullName = ActivePresentation.Path & "\" & "Book1.xlsx"    '**** dopasuj sobie
    Set XlApp = CreateObject("Excel.Application")
    ' XlApp.Visible = True               ' ****
    DoEvents
    Set XlWkb = XlApp.workbooks.Open(strXlFullName)
    With XlWkb
        .Worksheets("Sheet2").Range("A2").Value = Me.TextBox1_A.Value
        .Save
        .Close False
    End With
    Set XlWkb = Nothing
    Zapisz = True
    '---------------------
Zapisz_Exit:
    On Error Resume Next
    If Not (XlApp Is Nothing) Then
        If Not (XlWkb Is Nothing) Then
            XlWkb.Close False
            Set XlWkb = Nothing
        End If
        XlApp.Quit
        Set XlApp = Nothing
    End If
    Exit Function

Zapisz_Error:
    MsgBox "Bd Nr: " & Err.Number & vbNewLine & _
           "Opis bdu:" & Err.Description & vbNewLine & _
           "Procedura Zapisz "
    Resume Zapisz_Exit
End Function
Powrt do gry
Zobacz profil autora Wylij prywatn wiadomo
ireks



Doczy: 01 Lis 2007
Posty: 8

PostWysany: Wto Sie 15, 2017 11:57 am  OP    Temat postu: PP do Excela Odpowiedz z cytatem Pisownia

KarolinkaVB, Samolot,

dzieki za pomoc, jest ok
Powrt do gry
Zobacz profil autora Wylij prywatn wiadomo
Wywietl posty z ostatnich:   
Odpowiedz do tematu    Forum Coders' city Strona Gwna -> Oprogramowanie biurowe Wszystkie czasy w strefie CET (Europa)

Strona 1 z 1

 
Skocz do:  
Moesz pisa nowe tematy
Moesz odpowiada w tematach
Nie moesz zmienia swoich postw
Nie moesz usuwa swoich postw
Nie moesz gosowa w ankietach
Moesz dodawa zaczniki na tym forum
Moesz pobiera pliki z tego forum




Debug: strone wygenerowano w 0.14755 sekund, zapytan = 11
contact

| Darmowe programy i porady Jelcyna | Tansze zakupy w Helionie | MS Office Blog |